|\^/|     Maple 2022 (X86 64 LINUX)
._|\|   |/|_. Copyright (c) Maplesoft, a division of Waterloo Maple Inc. 2022
 \  MAPLE  /  All rights reserved. Maple is a trademark of
 <____ ____>  Waterloo Maple Inc.
      |       Type ? for help.
> BareissEdmondsDicksonSolve := proc(A::Matrix,b::Vector,n::posint)
> local B,d,i,j,k,y,x;
>    B := <A|b>;
>    d := 1;
>    for k to n-1 do
>      for i from k+1 to n do
>         for j from k+1 to n+1 do
>             B[i,j] := iquo(B[k,k]*B[i,j]-B[i,k]*B[k,j],d);
>         od;
>         B[i,k] := 0;
>      od;
>      d := B[k,k];
>    od;
>    print(B);
>    y := Vector(n):
>    y[n] := B[n,n+1];
>    for i from n-1 by -1 to 1 do
>       y[i] := iquo(B[i,n+1]*B[n,n]-add(B[i,j]*y[j],j=i+1..n),B[i,i]);
>    od;
>    x := Vector(n):
>    for i to n do 
>       x[i] := y[i]/B[n,n]; # B[n,n] = det(A) 
>    od;
>    x;
> end:
> A := Matrix([[3,2,3],[5,3,1],[2,6,4]]);
                                    [3    2    3]
                                    [           ]
                               A := [5    3    1]
                                    [           ]
                                    [2    6    4]

> b := <1,2,3>;
                                         [1]
                                         [ ]
                                    b := [2]
                                         [ ]
                                         [3]

> x := BareissEdmondsDicksonSolve(A,b,3);
                             [3     2      3     1]
                             [                    ]
                             [0    -1    -12     1]
                             [                    ]
                             [0     0     54    -7]

                                       [5/54]
                                       [    ]
                                       [5/9 ]
                                  x := [    ]
                                       [ -7 ]
                                       [ -- ]
                                       [ 54 ]

> A.x = b;
                                   [1]   [1]
                                   [ ]   [ ]
                                   [2] = [2]
                                   [ ]   [ ]
                                   [3]   [3]